Fix double-free in edit functionality (double-closing file handle).

* `--yesterday` is like `--today`, but for yesterday 😄.
* `--or` changes the behavior of filter criteria to return a union of
  events matching an of the criteria than an intersection of events
  matching all the criteria. Example:

      ptk list --today --yesterday

  Will never return results (because the criteria are mutually
  exclusive).

      ptk list --today --or --yesterday

  Will return the marks for both today and yesterday.

README.md

@@ -0,0 +1,14 @@
+# Personal Time Keeper
+
+`ptk` is a small utility to log time entries. It uses a simple conceptual model
+and a simple JSON data format.
+
+A ptk timeline is made up of a series of ptk entries, or marks. Each mark has a
+summary, a timestamp, and a universally unique id (generated by `ptk`).
+Additionally a mark may be tagged with an arbitrary number of tags and may have
+detailed notes attached to it (anything representable in plain text).
+
+The duration of a task is calculated by taking the difference between that
+task's timestamp and the one following it chronologically. The `STOP` value as
+a summary serves as a sentinal to indicate that an entry has been completed
+and no new entry is being tracked.

TODO.md

@@ -0,0 +1 @@
+* Sync with web timestamper.

private/api.nim

@@ -0,0 +1,253 @@
+## Personal Time Keeping API Interface
+## ===================================
+
+import asyncdispatch, base64, bcrypt, cliutils, docopt, jester, json, logging,
+  ospaths, sequtils, strutils, os, tables, times, uuids
+
+import nre except toSeq
+
+import ./models
+import ./util
+import ./version
+
+type
+  PtkUser* = object
+    username*, salt*, pwdhash*, timelinePath*: string
+    isAdmin*: bool
+
+  PtkApiCfg* = object
+    users*: seq[PtkUser]
+    port*: int
+    dataDir*: string
+
+const TXT = "text/plain"
+const JSON = "application/json"
+
+proc parseUser(json: JsonNode): PtkUser =
+  result = Ptkuser(
+    username: json.getOrFail("username").getStr,
+    salt: json.getOrFail("salt").getStr,
+    pwdHash: json.getOrFail("pwdhash").getStr,
+    timelinePath: json.getOrFail("timelinePath").getStr,
+    isAdmin: json.getIfExists("isAdmin").getBool(false))
+
+proc loadApiConfig*(json: JsonNode): PtkApiCfg =
+  result = PtkApiCfg(
+    port: parseInt(json.getIfExists("port").getStr("3280")),
+    dataDir: json.getOrFail("dataDir").getStr,
+    users: json.getIfExists("users").getElems(@[]).mapIt(parseUser(it)))
+
+template halt(code: HttpCode,
+              headers: RawHeaders,
+              content: string): typed =
+  ## Immediately replies with the specified request. This means any further
+  ## code will not be executed after calling this template in the current
+  ## route.
+  bind TCActionSend, newHttpHeaders
+  result[0] = CallbackAction.TCActionSend
+  result[1] = code
+  result[2] = some(headers)
+  result[3] = content
+  result.matched = true
+  break allRoutes
+
+
+template checkAuth(cfg: PtkApiCfg) =
+  ## Check this request for authentication and authorization information.
+  ## If the request is not authorized, this template immediately returns a
+  ## 401 Unauthotized response 
+
+  var authed {.inject.} = false
+  var user {.inject.}: PtkUser = PtkUser()
+
+  try:
+    if not request.headers.hasKey("Authorization"):
+      raiseEx "No auth token."
+
+    let headerVal = request.headers["Authorization"]
+    if not headerVal.startsWith("Basic "):
+      raiseEx "Invalid Authorization type (only 'Basic' is supported)."
+
+    let authVals = headerVal[6..^1].decode().split(":")
+
+    let candidates = cfg.users.filterIt(it.username.compare(authVals[0]))
+    if candidates.len != 1: raiseEx "Invalid Authorization: unknown username/password combination."
+
+    let foundUser: PtkUser = candidates[0]
+    if not compare(foundUser.pwdhash, hash(authVals[1], foundUser.salt)):
+      raiseEx "Invalid Authorization: unknown username/password combination."
+
+    user = foundUser
+    authed = true
+
+  except:
+    stderr.writeLine "Auth failed: " & getCurrentExceptionMsg()
+    halt(
+      Http401,
+      @{"Content-Type": TXT, "WWW_Authenticate": "Basic" },
+      getCurrentExceptionMsg())
+
+proc parseAndRun(user: PtkUser, cmd: string, params: Table[string, string]): string =
+
+  var args = queryParamsToCliArgs(params)
+  args = @[cmd, "--file", user.timelinePath] & args
+
+  info "args: \n" & args.join(" ")
+
+  let execResult = execWithOutput("ptk", ".", args)
+  if execResult[2] != 0: raiseEx(stripAnsi($execResult[0] & "\n" & $execResult[1]))
+  else: return stripAnsi(execResult[0])
+
+proc apiParseUser(json: JsonNode): PtkUser =
+  let salt = genSalt(12)
+
+  return PtkUser(
+    username: json.getOrFail("username").getStr,
+    pwdhash: json.getOrFail("password").getStr.hash(salt),
+    salt: salt,
+    timelinePath: json.getIfExists("timelinePath").getStr(""),
+    isAdmin: false)
+
+proc apiParseMark(json: JsonNode): Mark =
+
+  if not json.hasKey("id"): json["id"] = %($genUUID())
+  if not json.hasKey("summary"): raiseEx "cannot parse mark: missing 'summary'"
+  if not json.hasKey("time"): json["time"] = %(getTime().local.format(ISO_TIME_FORMAT))
+
+  return parseMark(json)
+
+proc patchMark(m: Mark, j: JsonNode): Mark =
+  result = m
+
+  if j.hasKey("summary"): result.summary = j["summary"].getStr
+  if j.hasKey("notes"): result.notes = j["notes"].getStr
+  if j.hasKey("tags"):
+    result.tags = j["tags"].getElems(@[]).map(proc (t: JsonNode): string = t.getStr())
+  if j.hasKey("time"): result.time = parse(j["time"].getStr(), ISO_TIME_FORMAT)
+
+proc start_api*(cfg: PtkApiCfg) =
+
+  var stopFuture = newFuture[void]()
+
+  settings:
+    port = Port(cfg.port)
+    appName = "/api"
+
+  routes:
+
+    get "/version": resp("ptk v" & PTK_VERSION, TXT)
+
+    get "/marks":
+      checkAuth(cfg)
+
+      try: resp(parseAndRun(user, "list", request.params), TXT)
+      except: resp(Http500, getCurrentExceptionMsg(), TXT)
+
+    post "/continue":
+      checkAuth(cfg)
+
+      try: resp(parseAndRun(user, "continue", request.params), TXT)
+      except: resp(Http500, getCurrentExceptionMsg(), TXT)
+
+    post "/sum-time":
+      checkAuth(cfg)
+
+      try: resp(parseAndRun(user, "sum-time", request.params), TXT)
+      except: resp(Http500, getCurrentExceptionMsg(), TXT)
+
+    post "/mark":
+      checkAuth(cfg)
+
+      var newMark: Mark
+      try: newMark = apiParseMark(parseJson(request.body))
+      except: resp(Http400, getCurrentExceptionMsg(), TXT)
+
+      try:
+        var timeline = loadTimeline(user.timelinePath)
+        timeline.marks.add(newMark)
+        saveTimeline(timeline, user.timelinePath)
+        resp(Http201, "ok", TXT)
+      except: resp(Http500, getCurrentExceptionMsg(), TXT)
+
+    post "/stop":
+      checkAuth(cfg)
+
+      var newMark: Mark
+      try:
+        var json = parseJson(request.body)
+        json["summary"] = %STOP_MSG
+        json["id"] = %($genUUID())
+        newMark = apiParseMark(json)
+      except: resp(Http400, getCurrentExceptionMsg(), TXT)
+
+      try:
+        var timeline = loadTimeline(user.timelinePath)
+        timeline.marks.add(newMark)
+        saveTimeline(timeline, user.timelinePath)
+        resp(Http201, "ok", TXT)
+      except: resp(Http500, getCurrentExceptionMsg(), TXT)
+
+    post "/resume/@id":
+      checkAuth(cfg)
+
+      var timeline: Timeline
+      try: timeline = loadTimeline(user.timelinePath)
+      except: resp(Http500, getCurrentExceptionMsg(), TXT)
+
+      var newMark: Mark
+      try:
+        let origMarkIdx = timeline.marks.findById(@"id")
+        if origMarkIdx < 0: resp(Http404, "no mark for id: " & @"id", TXT)
+        let origMark = timeline.marks[origMarkIdx]
+
+        newMark = origMark
+        newMark.id = genUUID()
+        newMark.time = getTime().local
+        newMark = newMark.patchMark(parseJson(request.body))
+      except: resp(Http400, getCurrentExceptionMsg(), TXT)
+
+      try:
+        timeline.marks.add(newMark)
+        timeline.saveTimeline(user.timelinePath)
+        resp(Http201, "ok", TXT)
+
+      except: resp(Http500, getCurrentExceptionMsg(), TXT)
+
+    post "/amend/@id":
+      checkAuth(cfg)
+
+      try:
+        var timeline = loadTimeline(user.timelinePath)
+
+        let idx = timeline.marks.findById(@"id")
+        if idx < 0: resp(Http404, "no mark for id: " & @"id", TXT)
+
+        timeline.marks[idx] = timeline.marks[idx].patchMark(parseJson(request.body))
+
+        timeline.saveTimeline(user.timelinePath)
+        resp(Http202, $(%timeline.marks[idx]), JSON)
+
+      except: resp(Http500, getCurrentExceptionMsg(), TXT)
+
+    post "/users":
+      checkAuth(cfg)
+      if not user.isAdmin: resp(Http403, "insufficient permission", TXT)
+
+      var newUser: PtkUser
+      try: newUser = apiParseUser(parseJson(request.body))
+      except: resp(Http400, getCurrentExceptionMsg(), TXT)
+
+      if cfg.users.anyIt(it.username == newUser.username):
+        resp(Http409, "user already exists", TXT)
+
+      newUser.timelinePath = cfg.dataDir / newUser.username & ".timeline.json"
+
+      try:
+        discard parseAndRun(newUser, "init", initTable[string,string]())
+        # TODO: save updated config!
+        # cfg.users.add(newUser)
+        resp(Http200, "ok", TXT)
+
+      except: resp(Http500, "could not init new user timeline", TXT)
+
+  waitFor(stopFuture)

private/models.nim

@@ -0,0 +1,116 @@
+import algorithm, json, sequtils, strutils, times, timeutils, uuids
+
+import ./util
+
+type
+  Mark* = tuple[id: UUID, time: DateTime, summary: string, notes: string, tags: seq[string]]
+    ## Representation of a single mark on the timeline.
+
+  Timeline* = tuple[name: string, marks: seq[Mark]]
+    ## Representation of a timeline: a name and sequence of Marks.
+
+const STOP_MSG* = "STOP"
+
+let NO_MARK*: Mark = (
+  id: parseUUID("00000000-0000-0000-0000-000000000000"),
+  time: fromUnix(0).local,
+  summary: "", notes: "", tags: @[])
+
+const ISO_TIME_FORMAT* = "yyyy-MM-dd'T'HH:mm:ss"
+  ## The canonical time format used by PTK.
+
+const TIME_FORMATS* = @[
+    "yyyy-MM-dd'T'HH:mm:ss", "yyyy-MM-dd HH:mm:ss",
+    "yyyy-MM-dd'T'HH:mm", "yyyy-MM-dd HH:mm",
+    "MM-dd'T'HH:mm:ss", "MM-dd HH:mm:ss",
+    "MM-dd'T'HH:mm", "MM-dd HH:mm",
+    "HH:mm:ss", "H:mm:ss", "H:mm", "HH:mm" ]
+  ## Other time formats that PTK will accept as input.
+
+proc getOrFail*(n: JsonNode, key: string, objName: string = ""): JsonNode =
+  ## convenience method to get a key from a JObject or raise an exception
+  if not n.hasKey(key): raiseEx objName & " missing key '" & key & "'"
+  return n[key]
+
+proc getIfExists*(n: JsonNode, key: string): JsonNode =
+  ## convenience method to get a key from a JObject or return null
+  result = if n.hasKey(key): n[key]
+           else: newJNull()
+
+proc parseTime*(timeStr: string): DateTime =
+  ## Helper to parse time strings trying multiple known formats.
+  for fmt in TIME_FORMATS:
+    try: return parse(timeStr, fmt)
+    except: discard nil
+
+  raise newException(Exception, "unable to interpret as a date: " & timeStr)
+
+proc parseMark*(json: JsonNode): Mark =
+
+  return (
+      id: parseUUID(json["id"].getStr()),
+      time: parse(json["time"].getStr(), ISO_TIME_FORMAT),
+      summary: json["summary"].getStr(),
+      notes: json["notes"].getStr(),
+      tags: json["tags"].getElems(@[]).map(proc (t: JsonNode): string = t.getStr()))
+
+template `%`*(mark: Mark): JsonNode =
+  %* {
+    "id": $(mark.id),
+    "time": mark.time.format(ISO_TIME_FORMAT),
+    "summary": mark.summary,
+    "notes": mark.notes,
+    "tags": mark.tags
+  }
+
+template `%`*(timeline: Timeline): JsonNode =
+  %* { "name": timeline.name, "marks": timeline.marks }
+
+proc loadTimeline*(filename: string): Timeline =
+  ## Load a timeline from a file. Expects a path to a file (can be relative or
+  ## absolute) and returns a Timeline. The marks in the timeline are guaranteed
+  ## to be ordered by time.
+
+  var timelineJson: JsonNode
+  try: timelineJson = parseFile(filename)
+  except:
+    raise newException(ValueError,
+      "unable to parse the timeline file as JSON: " & filename)
+
+  var timeline: Timeline = (name: timelineJson["name"].getStr(), marks: @[])
+
+  for markJson in timelineJson["marks"]: timeline.marks.add(parseMark(markJson))
+
+  timeline.marks = timeline.marks.sorted(
+    proc(a, b: Mark): int = cmp(a.time, b.time))
+
+  return timeline
+
+proc saveTimeline*(timeline: Timeline, location: string): void =
+  ## Write the timeline to disk at the file location given.
+
+  var timelineFile: File
+  try:
+    timelineFile = open(location, fmWrite)
+    timelineFile.writeLine(pretty(%timeline))
+  except: raise newException(IOError, "unable to save changes to " & location)
+  finally: close(timelineFile)
+
+proc findById*(marks: seq[Mark], id: string): int =
+  var idx = 0
+  for mark in marks:
+    if startsWith($mark.id, id): return idx
+    inc(idx)
+
+  return -1
+
+proc getLastIndex*(marks: seq[Mark]): int =
+  ## Find and return the index of the last Mark that was not a STOP mark.
+  ## Returns -1 if there is no such last mark.
+
+  var idx = marks.len - 1
+  while idx >= 0 and marks[idx].summary == STOP_MSG: idx -= 1
+  if idx < 0: result = -1
+  else: result = idx
+
+

private/util.nim

@@ -0,0 +1,11 @@
+template first*(a: openarray): auto = a[0]
+
+template last*(a: openarray): auto = a[len(a)-1]
+
+proc flatten*[T](a: seq[seq[T]]): seq[T] =
+  result = @[]
+  for subseq in a:
+    result.add(subseq)
+
+
+proc raiseEx*(reason: string): void = raise newException(Exception, reason)

private/version.nim

@@ -0,0 +1 @@
+const PTK_VERSION* = "1.0.3"

ptk.nim

@@ -3,26 +3,15 @@
 ##
 ## Simple time keeping CLI
 
-import algorithm, docopt, json, langutils, logging, os, sequtils, strutils,
-  tempfile, terminal, times, timeutils, uuids
-import ptkutil
+import algorithm, docopt, json, langutils, logging, os, nre, sequtils,
+  sets, strutils, tempfile, terminal, times, uuids
 
-type
-  Mark* = tuple[id: UUID, time: TimeInfo, summary: string, notes: string, tags: seq[string]]
-  Timeline* = tuple[name: string, marks: seq[Mark]]
+import timeutils except `-`;
 
-const STOP_MSG = "STOP"
-
-let NO_MARK: Mark = (
-  id: parseUUID("00000000-0000-0000-0000-000000000000"),
-  time: getLocalTime(getTime()),
-  summary: "", notes: "", tags: @[])
-
-const ISO_TIME_FORMAT = "yyyy:MM:dd'T'HH:mm:ss"
-
-const TIME_FORMATS = @[
-    "H:mm", "HH:mm", "H:mm:ss", "HH:mm:ss",
-    "yyyy:MM:dd'T'HH:mm:ss", "yyyy:MM:dd'T'HH:mm"]
+import private/util
+import private/api
+import private/models
+import private/version
 
 #proc `$`*(mark: Mark): string =
   #return (($mark.uuid)[
@@ -31,139 +20,92 @@ proc exitErr(msg: string): void =
   fatal "ptk: " & msg
   quit(QuitFailure)
 
-proc parseTime(timeStr: string): TimeInfo =
-  for fmt in TIME_FORMATS:
-    try: return parse(timeStr, fmt)
-    except: discard nil
+proc flexFormat(i: Duration): string =
+  ## Pretty-format a time interval.
 
-  raise newException(Exception, "unable to interpret as a date: " & timeStr)
-
-template `%`(mark: Mark): JsonNode =
-  %* {
-    "id": $(mark.id),
-    "time": mark.time.format(ISO_TIME_FORMAT),
-    "summary": mark.summary,
-    "notes": mark.notes,
-    "tags": mark.tags
-  }
-
-template `%`(timeline: Timeline): JsonNode =
-  %* { "name": timeline.name, "marks": timeline.marks }
-
-proc loadTimeline(filename: string): Timeline =
-  var timelineJson: JsonNode
-  try: timelineJson = parseFile(filename)
-  except:
-    raise newException(ValueError,
-      "unable to parse the timeline file as JSON: " & filename)
-
-  var timeline: Timeline = (name: timelineJson["name"].getStr(), marks: @[])
-
-  for markJson in timelineJson["marks"]:
-    timeline.marks.add((
-      id: parseUUID(markJson["id"].getStr()),
-      time: parse(markJson["time"].getStr(), ISO_TIME_FORMAT),
-      summary: markJson["summary"].getStr(),
-      notes: markJson["notes"].getStr(),
-      tags: markJson["tags"].getElems(@[]).map(proc (t: JsonNode): string = t.getStr())))
-
-  return timeline
-
-proc saveTimeline(timeline: Timeline, location: string): void =
-  var timelineFile: File
-  try:
-    timelineFile = open(location, fmWrite)
-    timelineFile.writeLine(pretty(%timeline))
-  except: raise newException(IOError, "unable to save changes to " & location)
-  finally: close(timelineFile)
-
-proc flexFormat(i: TimeInterval): string =
   let fmt =
-    if i > 1.days: "d'd' H'h' m'm'"
-    elif i >= 1.hours: "H'h' m'm'"
-    elif i >= 1.minutes: "m'm' s's'"
+    if i > initDuration(days = 1): "d'd' H'h' m'm'"
+    elif i >= initDuration(hours = 1): "H'h' m'm'"
+    elif i >= initDuration(minutes = 1): "m'm' s's'"
     else: "s's'"
 
   return i.format(fmt)
 
-proc writeMarks(marks: seq[Mark], includeNotes = false): void =
-  let now = getLocalTime(getTime())
+type WriteData = tuple[idx: int, mark: Mark, prefixLen: int, interval: Duration]
 
+proc writeMarks(timeline: Timeline, indices: seq[int], includeNotes = false): void =
+  ## Write a nicely-formatted list of Marks to stdout.
+
+  let marks = timeline.marks
+  let now = getTime().local
+
+  if indices.len == 0:
+    writeLine(stdout, "No marks match the given criteria.")
+    return
+
+  var idxs = indices.sorted(
+    proc(a, b: int): int = cmp(marks[a].time, marks[b].time))
+
+  let largestInterval = now - marks[idxs.first].time
   let timeFormat =
-    if now - marks.first.time > 1.years: "yyyy-MM-dd HH:mm"
-    elif now - marks.first.time > 7.days: "MMM dd HH:mm"
-    elif now - marks.first.time > 1.days: "ddd HH:mm"
+    if largestInterval > initDuration(days = 365): "yyyy-MM-dd HH:mm"
+    elif largestInterval > initDuration(days = 7): "MMM dd HH:mm"
+    elif largestInterval > initDuration(days = 1): "ddd HH:mm"
     else: "HH:mm"
 
-  var intervals: seq[TimeInterval] = @[]
-  for i in 0..<marks.len - 1: intervals.add(marks[i+1].time - marks[i].time)
-  intervals.add(now - marks.last.time)
+  var toWrite: seq[WriteData] = @[]
 
-  var prefixLens: seq[int] = @[]
   var longestPrefix = 0
-  for i in 0..<marks.len:
-    let
-      mark = marks[i]
-      interval = intervals[i]
-      prefix = ($mark.id)[0..<8] & "  " & mark.time.format(timeFormat) & " (" & interval.flexFormat & ")"
 
-    prefixLens.add(prefix.len)
+  for i in idxs:
+    let
+      interval: Duration =
+        if (i == marks.len - 1): now - marks[i].time
+        else: marks[i + 1].time - marks[i].time
+      prefix =
+        ($marks[i].id)[0..<8] & "  " & marks[i].time.format(timeFormat) &
+        " (" & interval.flexFormat & ")"
+
+    toWrite.add((
+      idx: i,
+      mark: marks[i],
+      prefixLen: prefix.len,
+      interval: interval))
+
     if prefix.len > longestPrefix: longestPrefix = prefix.len
 
-  for i in 0..<marks.len:
-    let mark = marks[i]
+  let colWidth = 80
+  let notesPrefixLen = 4
 
-    if mark.summary == STOP_MSG: continue
+  for w in toWrite:
+    if w.mark.summary == STOP_MSG: continue
 
-    let duration = intervals[i].flexFormat
     setForegroundColor(stdout, fgBlack, true)
-    write(stdout, ($mark.id)[0..<8])
+    write(stdout, ($w.mark.id)[0..<8])
     setForegroundColor(stdout, fgYellow)
-    write(stdout, "  " & mark.time.format(timeFormat))
+    write(stdout, "  " & w.mark.time.format(timeFormat))
     setForegroundColor(stdout, fgCyan)
-    write(stdout, " (" & duration & ")")
+    write(stdout, " (" & w.interval.flexFormat & ")")
     resetAttributes(stdout)
-    write(stdout, spaces(longestPrefix - prefixLens[i]) & " -- " & mark.summary)
+    write(stdout, spaces(longestPrefix - w.prefixLen) & " -- " & w.mark.summary)
 
-    if mark.tags.len > 0:
+    if w.mark.tags.len > 0:
       setForegroundColor(stdout, fgGreen)
-      write(stdout, " (" & mark.tags.join(", ") & ")")
+      write(stdout, " (" & w.mark.tags.join(", ") & ")")
       resetAttributes(stdout)
 
     writeLine(stdout, "")
 
-    if includeNotes and len(mark.notes.strip) > 0:
-      writeLine(stdout, spaces(longestPrefix) & mark.notes)
+    if includeNotes and len(w.mark.notes.strip) > 0:
       writeLine(stdout, "")
-
-proc formatMark(mark: Mark, nextMark = NO_MARK, timeFormat = ISO_TIME_FORMAT, includeNotes = false): string =
-
-  let nextTime =
-    if nextMark == NO_MARK: getLocalTime(getTime())
-    else: nextMark.time
-
-  let duration = (nextTime - mark.time).flexFormat
-  # TODO: pick up here calculating the time between marks
-
-  let prefix = ($mark.id)[0..<8] & "  " & mark.time.format(timeFormat) & " (" & duration & ") -- "
-  let prefixLen = len(($mark.id)[0..<8] & "  " & mark.time.format(timeFormat) & " (" & duration & ") -- ")
-
-  result = prefix & mark.summary
-  if includeNotes and len(mark.notes.strip()) > 0:
-    let wrappedNotes = wordWrap(s = mark.notes, maxLineWidth = 80 - prefixLen)
+      let wrappedNotes = wordWrap(s = w.mark.notes,
+                                  maxLineWidth = colWidth)
       for line in splitLines(wrappedNotes):
-      result &= "\x0D\x0A" & spaces(prefixLen) & line
-    result &= "\x0D\x0A"
-
-proc findById(marks: seq[Mark], id: string): int =
-  var idx = 0
-  for mark in marks:
-    if startsWith($mark.id, id): return idx
-    inc(idx)
-
-  return -1
+        writeLine(stdout, spaces(notesPrefixLen) & line)
+      writeLine(stdout, "")
 
 proc doInit(timelineLocation: string): void =
+  ## Interactively initialize a new timeline at the given file path.
 
   stdout.write "Time log name [New Timeline]: "
   let name = stdin.readLine()
@@ -182,6 +124,9 @@ proc doInit(timelineLocation: string): void =
 type ExpectedMarkPart = enum Time, Summary, Tags, Notes
 
 proc edit(mark: var Mark): void =
+  ## Interactively edit a mark using the editor named in the environment
+  ## variable "EDITOR"
+
   var
     tempFile: File
     tempFileName: string
@@ -199,6 +144,7 @@ proc edit(mark: var Mark): void =
 # notes for this timeline mark.""")
 
     close(tempFile)
+    tempFile = nil
 
     discard os.execShellCmd "$EDITOR " & tempFileName & " </dev/tty >/dev/tty"
 
@@ -215,20 +161,105 @@ proc edit(mark: var Mark): void =
 
   finally: close(tempFile)
 
+proc filterMarkIndices(timeline: Timeline, args: Table[string, Value]): seq[int] =
+  ## Filter down a set of marks according to options provided in command line
+  ## arguments.
+
+  let marks = timeline.marks
+  let now = getTime().local
+  let allIndices = sequtils.toSeq(0..<marks.len).filterIt(marks[it].summary != STOP_MSG).toSet
+  let union = args["--or"]
+
+  var selected =
+    if union: initSet[int]()
+    else: allIndices
+
+  template filterMarks(curSet: HashSet[int], pred: untyped): untyped =
+    var res: HashSet[int] = initSet[int]()
+    if union:
+      for mIdx {.inject.} in allIndices:
+        if pred: res.incl(mIdx)
+      res = res + curSet
+    else:
+      for mIdx {.inject.} in curSet:
+        if pred: res.incl(mIdx)
+    res
+
+  if args["<firstId>"]:
+    let idx = marks.findById($args["<firstId>"])
+    if idx > 0: selected = selected.filterMarks(mIdx >= idx)
+
+  if args["<lastId>"]:
+    let idx = marks.findById($args["<lastId>"])
+    if (idx > 0): selected = selected.filterMarks(mIdx <= idx)
+
+  if args["--after"]:
+    var startTime: DateTime
+    try: startTime = parseTime($args["--after"])
+    except: raise newException(ValueError,
+      "invalid value for --after: " & getCurrentExceptionMsg())
+    selected = selected.filterMarks(marks[mIdx].time > startTime)
+
+  if args["--before"]:
+    var endTime: DateTime
+    try: endTime = parseTime($args["--before"])
+    except: raise newException(ValueError,
+      "invalid value for --before: " & getCurrentExceptionMsg())
+    selected = selected.filterMarks(marks[mIdx].time < endTime)
+
+  if args["--today"]:
+    let b = now.startOfDay
+    let e = b + 1.days
+    selected = selected.filterMarks(marks[mIdx].time >= b and marks[mIdx].time < e)
+
+  if args["--yesterday"]:
+    let e = now.startOfDay
+    let b = e - 1.days
+    selected = selected.filterMarks(marks[mIdx].time >= b and marks[mIdx].time < e)
+
+  if args["--this-week"]:
+    let b = now.startOfWeek(dSun)
+    let e = b + 7.days
+    selected = selected.filterMarks(marks[mIdx].time >= b and marks[mIdx].time < e)
+
+  if args["--last-week"]:
+    let e = now.startOfWeek(dSun)
+    let b = e - 7.days
+    selected = selected.filterMarks(marks[mIdx].time >= b and marks[mIdx].time < e)
+
+  if args["--tags"]:
+    let tags = (args["--tags"] ?: "").split({',', ';'})
+    selected = selected.filterMarks(tags.allIt(marks[mIdx].tags.contains(it)))
+
+  if args["--remove-tags"]:
+    let tags = (args["--remove-tags"] ?: "").split({',', ';'})
+    selected = selected.filterMarks(not tags.allIt(marks[mIdx].tags.contains(it)))
+
+  if args["--matching"]:
+    let pattern = re("(?i)" & $(args["--matching"] ?: ""))
+    selected = selected.filterMarks(marks[mIdx].summary.find(pattern).isSome)
+
+  return sequtils.toSeq(selected.items).sorted(system.cmp)
+
 when isMainModule:
  try:
   let doc = """
 Usage:
   ptk init [options]
-  ptk add [options]
-  ptk add [options] <summary>
-  ptk amend [options] <id> [<summary>]
+  ptk (add | start) [options]
+  ptk (add | start) [options] <summary>
+  ptk resume [options] [<id>]
+  ptk amend [options] [<id>] [<summary>]
+  ptk merge <timeline> [<timeline>...]
   ptk stop [options]
   ptk continue
   ptk delete <id>
   ptk (list | ls) [options]
+  ptk (list | ls) tags
+  ptk current
   ptk sum-time --ids <ids>...
   ptk sum-time [options] [<firstId>] [<lastId>]
+  ptk serve-api <svcCfg> [--port <port>]
   ptk (-V | --version)
   ptk (-h | --help)
 
@@ -244,17 +275,24 @@ Options:
   -g --tags <tags>        Add the given tags (comma-separated) to the selected marks.
   -G --remove-tags <tagx> Remove the given tag from the selected marks.
   -h --help               Print this usage information.
+  -m --matching <pattern> Restric the selection to marks matching <pattern>.
   -n --notes <notes>      For add and amend, set the notes for a time mark.
   -t --time <time>        For add and amend, use this time instead of the current time.
+  -T --today              Restrict the selection to marks during today.
+  -Y --yesterday          Restrict the selection to marks during yesterday.
+  -w --this-week          Restrict the selection to marks during this week.
+  -W --last-week          Restrict the selection to marks during the last week.
+  -O --or                 Create a union from the time conditionals, not an intersection
+                          (e.g. --today --or --yesterday)
   -v --verbose            Include notes in timeline entry output.
 """
 
-# TODO: add    ptk delete [options]
 
   logging.addHandler(newConsoleLogger())
+  let now = getTime().local
 
   # Parse arguments
-  let args = docopt(doc, version = "ptk 0.2.1")
+  let args = docopt(doc, version = PTK_VERSION)
 
   if args["--echo-args"]: echo $args
 
@@ -264,7 +302,7 @@ Options:
 
   # Find and parse the .ptkrc file
   let ptkrcLocations = @[
-    if args["--config"]: $args["<cfgFile>"] else:"",
+    if args["--config"]: $args["--config"] else:"",
     ".ptkrc", $getEnv("PTKRC"), $getEnv("HOME") & "/.ptkrc"]
 
   var ptkrcFilename: string =
@@ -288,7 +326,7 @@ Options:
 
   # Find the time log file
   let timelineLocations = @[
-    if args["--file"]: $args["<file>"] else: "",
+    if args["--file"]: $args["--file"] else: "",
     $getEnv("PTK_FILE"),
     cfg["timelineLogFile"].getStr(""),
     "ptk.log.json"]
@@ -300,6 +338,30 @@ Options:
   if args["init"]:
     doInit(foldl(timelineLocations, if len(a) > 0: a else: b))
 
+  elif args["merge"]:
+
+    let filesToMerge = args["<timeline>"]
+    let timelines = filesToMerge.mapIt(loadTimeline(it))
+
+    let names = timelines.mapIt(it.name).toSet
+    let mergedName = sequtils.toSeq(names.items).foldl(a & " + " & b)
+    var merged: Timeline = (
+      name: mergedName,
+      marks: @[])
+
+    for timeline in timelines:
+      for mark in timeline.marks:
+        var existingMarkIdx = merged.marks.findById($mark.id)
+        if existingMarkIdx >= 0:
+          if merged.marks[existingMarkIdx].summary != mark.summary:
+            merged.marks[existingMarkIdx].summary &= " | " & mark.summary
+          if merged.marks[existingMarkIdx].notes != mark.notes:
+            merged.marks[existingMarkIdx].notes &= "\r\n--------\r\b" & mark.notes
+
+        else: merged.marks.add(mark)
+
+    writeLine(stdout, pretty(%merged))
+
   else:
 
     if not fileExists(timelineLocation):
@@ -310,69 +372,110 @@ Options:
 
     if args["stop"]:
 
+      if timeline.marks.last.summary == STOP_MSG:
+        echo "ptk: no current task, nothing to stop"
+        quit(0)
+
       let newMark: Mark = (
         id: genUUID(),
-        time:
-          if args["--time"]: parseTime($args["--time"])
-          else: getLocalTime(getTime()),
+        time: if args["--time"]: parseTime($args["--time"]) else: now,
         summary: STOP_MSG,
         notes: args["--notes"] ?: "",
-        tags: (args["--tags"] ?: "").split({',', ';'}))
+        tags: (args["--tags"] ?: "").split({',', ';'}).filterIt(not it.isNilOrWhitespace))
 
       timeline.marks.add(newMark)
-      writeMarks(
-        marks = timeline.marks[timeline.marks.len - 2..<timeline.marks.len],
+
+      timeline.writeMarks(
+        indices = @[timeline.marks.len - 2],
         includeNotes = args["--verbose"])
-      echo "stopped timer"
+      echo "ptk: stopped timer"
 
       saveTimeline(timeline, timelineLocation)
 
     if args["continue"]:
 
       if timeline.marks.last.summary != STOP_MSG:
-        echo "There is already something in progress:"
-        writeMarks(
-          marks = @[timeline.marks.last],
+        echo "ptk: there is already something in progress:"
+        timeline.writeMarks(
+          indices = @[timeline.marks.len - 1],
           includeNotes = args["--verbose"])
         quit(0)
 
       let prevMark = timeline.marks[timeline.marks.len - 2]
       var newMark: Mark = (
         id: genUUID(),
-        time:
-          if args["--time"]: parseTime($args["--time"])
-          else: getLocalTime(getTime()),
+        time: if args["--time"]: parseTime($args["--time"]) else: now,
         summary: prevMark.summary,
         notes: prevMark.notes,
         tags: prevMark.tags)
 
       timeline.marks.add(newMark)
-      writeMarks(marks = @[newMark], includeNotes = args["--verbose"])
+      timeline.writeMarks(
+        indices = @[timeline.marks.len - 1],
+        includeNotes = args["--verbose"])
 
       saveTimeline(timeline, timelineLocation)
 
-    if args["add"]:
+    if args["add"] or args["start"]:
 
       var newMark: Mark = (
         id: genUUID(),
-        time:
-          if args["--time"]: parseTime($args["--time"])
-          else: getLocalTime(getTime()),
+        time: if args["--time"]: parseTime($args["--time"]) else: now,
         summary: args["<summary>"] ?: "",
         notes: args["--notes"] ?: "",
-        tags: (args["--tags"] ?: "").split({',', ';'}))
+        tags: (args["--tags"] ?: "").split({',', ';'}).filterIt(not it.isNilOrWhitespace))
+
+      if args["--edit"]: edit(newMark)
+
+      let prevLastIdx = timeline.marks.getLastIndex()
+      timeline.marks.add(newMark)
+      timeline.writeMarks(
+        indices = if prevLastIdx < 0: @[0]
+                  else: @[prevLastIdx, timeline.marks.len - 1],
+        includeNotes = args["--verbose"])
+
+      saveTimeline(timeline, timelineLocation)
+
+    if args["resume"]:
+
+      var markToResumeIdx: int
+
+      if args["<id>"]:
+        markToResumeIdx = timeline.marks.findById($args["<id>"])
+        if markToResumeIdx == -1: exitErr "Cannot find a mark matching " & $args["<id>"]
+      else:
+        markToResumeIdx = timeline.marks.getLastIndex()
+        if markToResumeIdx < 0: exitErr "No mark to resume."
+      var markToResume = timeline.marks[markToResumeIdx]
+
+      var newMark: Mark = (
+        id: genUUID(),
+        time: if args["--time"]: parseTime($args["--time"]) else: now,
+        summary: markToResume.summary,
+        notes: markToResume.notes,
+        tags: markToResume.tags)
 
       if args["--edit"]: edit(newMark)
 
       timeline.marks.add(newMark)
-      writeMarks(marks = @[newMark], includeNotes = args["--verbose"])
+      timeline.writeMarks(
+        indices = sequtils.toSeq(markToResumeIdx..<timeline.marks.len),
+        includeNotes = args["--verbose"])
 
       saveTimeline(timeline, timelineLocation)
 
     if args["amend"]:
 
       # Note, this returns a copy, not a reference to the mark in the seq.
-      let markIdx = timeline.marks.findById($args["<id>"])
+      var markIdx: int
+
+      if args["<id>"]:
+        markIdx = timeline.marks.findById($args["<id>"])
+        if markIdx == -1: exitErr "Cannot find a mark matching " & $args["<id>"]
+      else:
+        markIdx = timeline.marks.getLastIndex()
+        if markIdx < 0: exitErr "No mark to amend."
+
       var mark = timeline.marks[markIdx]
 
       if args["<summary>"]: mark.summary = $args["<summary>"]
@@ -391,10 +494,14 @@ Options:
 
       if args["--edit"]: edit(mark)
 
-      writeMarks(marks = @[mark], includeNotes = args["--verbose"])
-
       timeline.marks.delete(markIdx)
       timeline.marks.insert(mark, markIdx)
+
+      timeline.writeMarks(
+        indices = @[markIdx],
+        includeNotes = args["--verbose"])
+
+
       saveTimeline(timeline, timelineLocation)
 
     if args["delete"]:
@@ -405,29 +512,31 @@ Options:
 
     if args["list"] or args["ls"]:
 
-      var marks = timeline.marks
+      if args["tags"]:
 
-      if args["--after"]:
-        var startTime: TimeInfo
-        try: startTime = parseTime($args["--after"])
-        except: raise newException(ValueError,
-          "invalid value for --after: " & getCurrentExceptionMsg())
-        marks = marks.filter(proc(m: Mark): bool = m.time > startTime)
+        echo $(timeline.marks.mapIt(it.tags)
+                .flatten().deduplicate().sorted(system.cmp).join("\n"))
 
-      if args["--before"]:
-        var endTime: TimeInfo
-        try: endTime = parseTime($args["--before"])
-        except: raise newException(ValueError,
-          "invalid value for --before: " & getCurrentExceptionMsg())
-        marks = marks.filter(proc(m: Mark): bool = m.time < endTime)
+      else:
+        var selectedIndices = timeline.filterMarkIndices(args)
 
-      marks = marks.sorted(proc(a, b: Mark): int = cmp(a.time, b.time))
+        timeline.writeMarks(
+          indices = selectedIndices,
+          includeNotes = args["--verbose"])
 
-      writeMarks(marks = marks, includeNotes = args["--version"])
+    if args["current"]:
+
+      let idx = timeline.marks.len - 1
+      if timeline.marks[idx].summary == STOP_MSG:
+        echo "ptk: no current task"
+      else:
+        timeline.writeMarks(
+          indices = @[idx],
+          includeNotes = true)
 
     if args["sum-time"]:
 
-      var intervals: seq[TimeInterval] = @[]
+      var intervals: seq[Duration] = @[]
 
       if args["--ids"]:
         for id in args["<ids>"]:
@@ -435,56 +544,35 @@ Options:
           if markIdx == -1:
             warn "ptk: could not find mark for id " & id
           elif markIdx == timeline.marks.len - 1:
-            intervals.add(getLocalTime(getTime()) - timeline.marks.last.time)
+            intervals.add(now - timeline.marks.last.time)
           else:
             intervals.add(timeline.marks[markIdx + 1].time - timeline.marks[markIdx].time)
 
       else:
 
-        var startIdx = 0
-        var endIdx = timeline.marks.len - 1
+        var indicesToSum = timeline.filterMarkIndices(args)
 
-        if args["<firstId>"]:
-          startIdx = max(timeline.marks.findById($args["<firstId>"]), 0)
-
-        if args["<lastId>"]:
-          let idx = timeline.marks.findById($args["<firstId>"])
-          if (idx > 0): endIdx = idx
-
-        if args["--after"]:
-          var startTime: TimeInfo
-          try: startTime = parseTime($args["--after"])
-          except: raise newException(ValueError,
-            "invalid value for --after: " & getCurrentExceptionMsg())
-          let marks = timeline.marks.filter(proc(m: Mark): bool = m.time > startTime)
-
-          let idx = timeline.marks.findById($marks.first.id)
-          if idx > startIdx: startIdx = idx
-
-        if args["--before"]:
-          var endTime: TimeInfo
-          try: endTime = parseTime($args["--before"])
-          except: raise newException(ValueError,
-            "invalid value for --after: " & getCurrentExceptionMsg())
-          let marks = timeline.marks.filter(proc(m: Mark): bool = m.time < endTime)
-
-          let idx = timeline.marks.findById($marks.last.id)
-          if idx < endIdx: endIdx = idx
-
-        for idx in startIdx..<min(endIdx, timeline.marks.len - 1):
-          if timeline.marks[idx].summary == STOP_MSG: continue # don't count stops
-          intervals.add(timeline.marks[idx + 1].time - timeline.marks[idx].time)
-
-        if endIdx == timeline.marks.len - 1 and
-           timeline.marks.last.summary != STOP_MSG:
-          intervals.add(getLocalTime(getTime()) - timeline.marks.last.time)
+        for idx in indicesToSum:
+          let mark = timeline.marks[idx]
+          if idx == timeline.marks.len - 1: intervals.add(now - mark.time)
+          else: intervals.add(timeline.marks[idx + 1].time - mark.time)
 
       if intervals.len == 0:
         echo "ptk: no marks found"
 
       else:
-        let total = foldl(intervals, a + b)
-        echo total.flexFormat
+        let total = intervals.foldl(a + b)
+        echo flexFormat(total)
+
+    if args["serve-api"]:
+
+      if not fileExists($args["<svcCfg>"]):
+        exitErr "cannot find service config file: '" & $args["<svcCfg>"]
+
+      var apiCfg = loadApiConfig(parseFile($args["<svcCfg>"]))
+      if args["--port"]: apiCfg.port = parseInt($args["--port"])
+
+      start_api(apiCfg)
 
  except:
   fatal "ptk: " & getCurrentExceptionMsg()

ptk.nimble

@@ -1,6 +1,6 @@
 # Package
 
-version       = "0.2.1"
+version       = "1.0.3"
 author        = "Jonathan Bernard"
 description   = "Personal Time Keeper"
 license       = "MIT"
@@ -8,5 +8,19 @@ bin           = @["ptk"]
 
 # Dependencies
 
-requires @["nim >= 0.15.0", "docopt >= 0.6.4", "uuids", "langutils", "tempfile", "timeutils"]
+requires @[
+  "nim >= 1.0.0",
+  "docopt >= 0.6.8",
+  "uuids",
+  "tempfile",
+  "isaac >= 0.1.3",
+  "bcrypt",
+  "jester 0.4.1",
+  "https://git.jdb-labs.com/jdb/nim-lang-utils.git",
+  "https://git.jdb-labs.com/jdb/nim-cli-utils.git",
+  "https://git.jdb-labs.com/jdb/nim-time-utils.git >= 0.5.2",
+  "https://git.jdb-labs.com/jdb/update-nim-package-version"
+]
 
+task updateVersion, "Update the version of this package.":
+  exec "update_nim_package_version ptk 'private/version.nim'"

ptkutil.nim

@@ -1,3 +0,0 @@
-template first*(s: seq): auto = s[0]
-
-template last*(s: seq): auto = s[len(s)-1]