Include notes when editing marks.

private/api.nim

@@ -0,0 +1,253 @@
+## Personal Time Keeping API Interface
+## ===================================
+
+import asyncdispatch, base64, bcrypt, cliutils, docopt, jester, json, logging,
+  ospaths, sequtils, strutils, os, tables, times, uuids
+
+import nre except toSeq
+
+import ./models
+import ./util
+import ./version
+
+type
+  PtkUser* = object
+    username*, salt*, pwdhash*, timelinePath*: string
+    isAdmin*: bool
+
+  PtkApiCfg* = object
+    users*: seq[PtkUser]
+    port*: int
+    dataDir*: string
+
+const TXT = "text/plain"
+const JSON = "application/json"
+
+proc parseUser(json: JsonNode): PtkUser =
+  result = Ptkuser(
+    username: json.getOrFail("username").getStr,
+    salt: json.getOrFail("salt").getStr,
+    pwdHash: json.getOrFail("pwdhash").getStr,
+    timelinePath: json.getOrFail("timelinePath").getStr,
+    isAdmin: json.getIfExists("isAdmin").getBool(false))
+
+proc loadApiConfig*(json: JsonNode): PtkApiCfg =
+  result = PtkApiCfg(
+    port: parseInt(json.getIfExists("port").getStr("3280")),
+    dataDir: json.getOrFail("dataDir").getStr,
+    users: json.getIfExists("users").getElems(@[]).mapIt(parseUser(it)))
+
+template halt(code: HttpCode,
+              headers: RawHeaders,
+              content: string): typed =
+  ## Immediately replies with the specified request. This means any further
+  ## code will not be executed after calling this template in the current
+  ## route.
+  bind TCActionSend, newHttpHeaders
+  result[0] = CallbackAction.TCActionSend
+  result[1] = code
+  result[2] = some(headers)
+  result[3] = content
+  result.matched = true
+  break allRoutes
+
+
+template checkAuth(cfg: PtkApiCfg) =
+  ## Check this request for authentication and authorization information.
+  ## If the request is not authorized, this template immediately returns a
+  ## 401 Unauthotized response 
+
+  var authed {.inject.} = false
+  var user {.inject.}: PtkUser = PtkUser()
+
+  try:
+    if not request.headers.hasKey("Authorization"):
+      raiseEx "No auth token."
+
+    let headerVal = request.headers["Authorization"]
+    if not headerVal.startsWith("Basic "):
+      raiseEx "Invalid Authorization type (only 'Basic' is supported)."
+
+    let authVals = headerVal[6..^1].decode().split(":")
+
+    let candidates = cfg.users.filterIt(it.username.compare(authVals[0]))
+    if candidates.len != 1: raiseEx "Invalid Authorization: unknown username/password combination."
+
+    let foundUser: PtkUser = candidates[0]
+    if not compare(foundUser.pwdhash, hash(authVals[1], foundUser.salt)):
+      raiseEx "Invalid Authorization: unknown username/password combination."
+
+    user = foundUser
+    authed = true
+
+  except:
+    stderr.writeLine "Auth failed: " & getCurrentExceptionMsg()
+    halt(
+      Http401,
+      @{"Content-Type": TXT, "WWW_Authenticate": "Basic" },
+      getCurrentExceptionMsg())
+
+proc parseAndRun(user: PtkUser, cmd: string, params: Table[string, string]): string =
+
+  var args = queryParamsToCliArgs(params)
+  args = @[cmd, "--file", user.timelinePath] & args
+
+  info "args: \n" & args.join(" ")
+
+  let execResult = execWithOutput("ptk", ".", args)
+  if execResult[2] != 0: raiseEx(stripAnsi($execResult[0] & "\n" & $execResult[1]))
+  else: return stripAnsi(execResult[0])
+
+proc apiParseUser(json: JsonNode): PtkUser =
+  let salt = genSalt(12)
+
+  return PtkUser(
+    username: json.getOrFail("username").getStr,
+    pwdhash: json.getOrFail("password").getStr.hash(salt),
+    salt: salt,
+    timelinePath: json.getIfExists("timelinePath").getStr(""),
+    isAdmin: false)
+
+proc apiParseMark(json: JsonNode): Mark =
+
+  if not json.hasKey("id"): json["id"] = %($genUUID())
+  if not json.hasKey("summary"): raiseEx "cannot parse mark: missing 'summary'"
+  if not json.hasKey("time"): json["time"] = %(getTime().local.format(ISO_TIME_FORMAT))
+
+  return parseMark(json)
+
+proc patchMark(m: Mark, j: JsonNode): Mark =
+  result = m
+
+  if j.hasKey("summary"): result.summary = j["summary"].getStr
+  if j.hasKey("notes"): result.notes = j["notes"].getStr
+  if j.hasKey("tags"):
+    result.tags = j["tags"].getElems(@[]).map(proc (t: JsonNode): string = t.getStr())
+  if j.hasKey("time"): result.time = parse(j["time"].getStr(), ISO_TIME_FORMAT)
+
+proc start_api*(cfg: PtkApiCfg) =
+
+  var stopFuture = newFuture[void]()
+
+  settings:
+    port = Port(cfg.port)
+    appName = "/api"
+
+  routes:
+
+    get "/version": resp("ptk v" & PTK_VERSION, TXT)
+
+    get "/marks":
+      checkAuth(cfg)
+
+      try: resp(parseAndRun(user, "list", request.params), TXT)
+      except: resp(Http500, getCurrentExceptionMsg(), TXT)
+
+    post "/continue":
+      checkAuth(cfg)
+
+      try: resp(parseAndRun(user, "continue", request.params), TXT)
+      except: resp(Http500, getCurrentExceptionMsg(), TXT)
+
+    post "/sum-time":
+      checkAuth(cfg)
+
+      try: resp(parseAndRun(user, "sum-time", request.params), TXT)
+      except: resp(Http500, getCurrentExceptionMsg(), TXT)
+
+    post "/mark":
+      checkAuth(cfg)
+
+      var newMark: Mark
+      try: newMark = apiParseMark(parseJson(request.body))
+      except: resp(Http400, getCurrentExceptionMsg(), TXT)
+
+      try:
+        var timeline = loadTimeline(user.timelinePath)
+        timeline.marks.add(newMark)
+        saveTimeline(timeline, user.timelinePath)
+        resp(Http201, "ok", TXT)
+      except: resp(Http500, getCurrentExceptionMsg(), TXT)
+
+    post "/stop":
+      checkAuth(cfg)
+
+      var newMark: Mark
+      try:
+        var json = parseJson(request.body)
+        json["summary"] = %STOP_MSG
+        json["id"] = %($genUUID())
+        newMark = apiParseMark(json)
+      except: resp(Http400, getCurrentExceptionMsg(), TXT)
+
+      try:
+        var timeline = loadTimeline(user.timelinePath)
+        timeline.marks.add(newMark)
+        saveTimeline(timeline, user.timelinePath)
+        resp(Http201, "ok", TXT)
+      except: resp(Http500, getCurrentExceptionMsg(), TXT)
+
+    post "/resume/@id":
+      checkAuth(cfg)
+
+      var timeline: Timeline
+      try: timeline = loadTimeline(user.timelinePath)
+      except: resp(Http500, getCurrentExceptionMsg(), TXT)
+
+      var newMark: Mark
+      try:
+        let origMarkIdx = timeline.marks.findById(@"id")
+        if origMarkIdx < 0: resp(Http404, "no mark for id: " & @"id", TXT)
+        let origMark = timeline.marks[origMarkIdx]
+
+        newMark = origMark
+        newMark.id = genUUID()
+        newMark.time = getTime().local
+        newMark = newMark.patchMark(parseJson(request.body))
+      except: resp(Http400, getCurrentExceptionMsg(), TXT)
+
+      try:
+        timeline.marks.add(newMark)
+        timeline.saveTimeline(user.timelinePath)
+        resp(Http201, "ok", TXT)
+
+      except: resp(Http500, getCurrentExceptionMsg(), TXT)
+
+    post "/amend/@id":
+      checkAuth(cfg)
+
+      try:
+        var timeline = loadTimeline(user.timelinePath)
+
+        let idx = timeline.marks.findById(@"id")
+        if idx < 0: resp(Http404, "no mark for id: " & @"id", TXT)
+
+        timeline.marks[idx] = timeline.marks[idx].patchMark(parseJson(request.body))
+
+        timeline.saveTimeline(user.timelinePath)
+        resp(Http202, $(%timeline.marks[idx]), JSON)
+
+      except: resp(Http500, getCurrentExceptionMsg(), TXT)
+
+    post "/users":
+      checkAuth(cfg)
+      if not user.isAdmin: resp(Http403, "insufficient permission", TXT)
+
+      var newUser: PtkUser
+      try: newUser = apiParseUser(parseJson(request.body))
+      except: resp(Http400, getCurrentExceptionMsg(), TXT)
+
+      if cfg.users.anyIt(it.username == newUser.username):
+        resp(Http409, "user already exists", TXT)
+
+      newUser.timelinePath = cfg.dataDir / newUser.username & ".timeline.json"
+
+      try:
+        discard parseAndRun(newUser, "init", initTable[string,string]())
+        # TODO: save updated config!
+        # cfg.users.add(newUser)
+        resp(Http200, "ok", TXT)
+
+      except: resp(Http500, "could not init new user timeline", TXT)
+
+  waitFor(stopFuture)

private/models.nim

@@ -0,0 +1,116 @@
+import algorithm, json, sequtils, strutils, times, timeutils, uuids
+
+import ./util
+
+type
+  Mark* = tuple[id: UUID, time: DateTime, summary: string, notes: string, tags: seq[string]]
+    ## Representation of a single mark on the timeline.
+
+  Timeline* = tuple[name: string, marks: seq[Mark]]
+    ## Representation of a timeline: a name and sequence of Marks.
+
+const STOP_MSG* = "STOP"
+
+let NO_MARK*: Mark = (
+  id: parseUUID("00000000-0000-0000-0000-000000000000"),
+  time: fromUnix(0).local,
+  summary: "", notes: "", tags: @[])
+
+const ISO_TIME_FORMAT* = "yyyy-MM-dd'T'HH:mm:ss"
+  ## The canonical time format used by PTK.
+
+const TIME_FORMATS* = @[
+    "yyyy-MM-dd'T'HH:mm:ss", "yyyy-MM-dd HH:mm:ss",
+    "yyyy-MM-dd'T'HH:mm", "yyyy-MM-dd HH:mm",
+    "MM-dd'T'HH:mm:ss", "MM-dd HH:mm:ss",
+    "MM-dd'T'HH:mm", "MM-dd HH:mm",
+    "HH:mm:ss", "H:mm:ss", "H:mm", "HH:mm" ]
+  ## Other time formats that PTK will accept as input.
+
+proc getOrFail*(n: JsonNode, key: string, objName: string = ""): JsonNode =
+  ## convenience method to get a key from a JObject or raise an exception
+  if not n.hasKey(key): raiseEx objName & " missing key '" & key & "'"
+  return n[key]
+
+proc getIfExists*(n: JsonNode, key: string): JsonNode =
+  ## convenience method to get a key from a JObject or return null
+  result = if n.hasKey(key): n[key]
+           else: newJNull()
+
+proc parseTime*(timeStr: string): DateTime =
+  ## Helper to parse time strings trying multiple known formats.
+  for fmt in TIME_FORMATS:
+    try: return parse(timeStr, fmt)
+    except: discard nil
+
+  raise newException(Exception, "unable to interpret as a date: " & timeStr)
+
+proc parseMark*(json: JsonNode): Mark =
+
+  return (
+      id: parseUUID(json["id"].getStr()),
+      time: parse(json["time"].getStr(), ISO_TIME_FORMAT),
+      summary: json["summary"].getStr(),
+      notes: json["notes"].getStr(),
+      tags: json["tags"].getElems(@[]).map(proc (t: JsonNode): string = t.getStr()))
+
+template `%`*(mark: Mark): JsonNode =
+  %* {
+    "id": $(mark.id),
+    "time": mark.time.format(ISO_TIME_FORMAT),
+    "summary": mark.summary,
+    "notes": mark.notes,
+    "tags": mark.tags
+  }
+
+template `%`*(timeline: Timeline): JsonNode =
+  %* { "name": timeline.name, "marks": timeline.marks }
+
+proc loadTimeline*(filename: string): Timeline =
+  ## Load a timeline from a file. Expects a path to a file (can be relative or
+  ## absolute) and returns a Timeline. The marks in the timeline are guaranteed
+  ## to be ordered by time.
+
+  var timelineJson: JsonNode
+  try: timelineJson = parseFile(filename)
+  except:
+    raise newException(ValueError,
+      "unable to parse the timeline file as JSON: " & filename)
+
+  var timeline: Timeline = (name: timelineJson["name"].getStr(), marks: @[])
+
+  for markJson in timelineJson["marks"]: timeline.marks.add(parseMark(markJson))
+
+  timeline.marks = timeline.marks.sorted(
+    proc(a, b: Mark): int = cmp(a.time, b.time))
+
+  return timeline
+
+proc saveTimeline*(timeline: Timeline, location: string): void =
+  ## Write the timeline to disk at the file location given.
+
+  var timelineFile: File
+  try:
+    timelineFile = open(location, fmWrite)
+    timelineFile.writeLine(pretty(%timeline))
+  except: raise newException(IOError, "unable to save changes to " & location)
+  finally: close(timelineFile)
+
+proc findById*(marks: seq[Mark], id: string): int =
+  var idx = 0
+  for mark in marks:
+    if startsWith($mark.id, id): return idx
+    inc(idx)
+
+  return -1
+
+proc getLastIndex*(marks: seq[Mark]): int =
+  ## Find and return the index of the last Mark that was not a STOP mark.
+  ## Returns -1 if there is no such last mark.
+
+  var idx = marks.len - 1
+  while idx >= 0 and marks[idx].summary == STOP_MSG: idx -= 1
+  if idx < 0: result = -1
+  else: result = idx
+
+

private/util.nim

@@ -6,3 +6,6 @@ proc flatten*[T](a: seq[seq[T]]): seq[T] =
   result = @[]
   for subseq in a:
     result.add(subseq)
+
+
+proc raiseEx*(reason: string): void = raise newException(Exception, reason)

private/version.nim

@@ -0,0 +1 @@
+const PTK_VERSION* = "1.0.4"

ptk.nim

@@ -4,34 +4,14 @@
 ## Simple time keeping CLI
 
 import algorithm, docopt, json, langutils, logging, os, nre, sequtils,
-  sets, strutils, tempfile, terminal, times, timeutils, uuids
+  sets, strutils, tempfile, terminal, times, uuids
 
-import private/ptkutil
+import timeutils except `-`;
 
-type
+import private/util
-  Mark* = tuple[id: UUID, time: DateTime, summary: string, notes: string, tags: seq[string]]
+import private/api
-    ## Representation of a single mark on the timeline.
+import private/models
-
+import private/version
-  Timeline* = tuple[name: string, marks: seq[Mark]]
-    ## Representation of a timeline: a name and sequence of Marks.
-
-const STOP_MSG = "STOP"
-
-let NO_MARK: Mark = (
-  id: parseUUID("00000000-0000-0000-0000-000000000000"),
-  time: fromUnix(0).local,
-  summary: "", notes: "", tags: @[])
-
-const ISO_TIME_FORMAT = "yyyy-MM-dd'T'HH:mm:ss"
-  ## The canonical time format used by PTK.
-
-const TIME_FORMATS = @[
-    "yyyy-MM-dd'T'HH:mm:ss", "yyyy-MM-dd HH:mm:ss",
-    "yyyy-MM-dd'T'HH:mm", "yyyy-MM-dd HH:mm",
-    "MM-dd'T'HH:mm:ss", "MM-dd HH:mm:ss",
-    "MM-dd'T'HH:mm", "MM-dd HH:mm",
-    "HH:mm:ss", "H:mm:ss", "H:mm", "HH:mm" ]
-  ## Other time formats that PTK will accept as input.
 
 #proc `$`*(mark: Mark): string =
   #return (($mark.uuid)[
@@ -40,82 +20,18 @@ proc exitErr(msg: string): void =
   fatal "ptk: " & msg
   quit(QuitFailure)
 
-proc parseTime(timeStr: string): DateTime =
+proc flexFormat(i: Duration): string =
-  ## Helper to parse time strings trying multiple known formats. 
-  for fmt in TIME_FORMATS:
-    try: return parse(timeStr, fmt)
-    except: discard nil
-
-  raise newException(Exception, "unable to interpret as a date: " & timeStr)
-
-template `%`(mark: Mark): JsonNode =
-  %* {
-    "id": $(mark.id),
-    "time": mark.time.format(ISO_TIME_FORMAT),
-    "summary": mark.summary,
-    "notes": mark.notes,
-    "tags": mark.tags
-  }
-
-template `%`(timeline: Timeline): JsonNode =
-  %* { "name": timeline.name, "marks": timeline.marks }
-
-proc loadTimeline(filename: string): Timeline =
-  ## Load a timeline from a file. Expects a path to a file (can be relative or
-  ## absolute) and returns a Timeline. The marks in the timeline are guaranteed
-  ## to be ordered by time.
-
-  var timelineJson: JsonNode
-  try: timelineJson = parseFile(filename)
-  except:
-    raise newException(ValueError,
-      "unable to parse the timeline file as JSON: " & filename)
-
-  var timeline: Timeline = (name: timelineJson["name"].getStr(), marks: @[])
-
-  for markJson in timelineJson["marks"]:
-
-    # TODO: an incorrect time format that was used in version 0.6 and prior.
-    # Version 0.7 between 1.0 support this format on read only and will write
-    # out the correct  format (so they can be used to convert older timelines).
-    var time: DateTime
-    try: time = parse(markJson["time"].getStr(), ISO_TIME_FORMAT)
-    except: time = parse(markJson["time"].getStr(), "yyyy:MM:dd'T'HH:mm:ss")
-
-    timeline.marks.add((
-      id: parseUUID(markJson["id"].getStr()),
-      time: time, #parse(markJson["time"].getStr(), ISO_TIME_FORMAT),
-      summary: markJson["summary"].getStr(),
-      notes: markJson["notes"].getStr(),
-      tags: markJson["tags"].getElems(@[]).map(proc (t: JsonNode): string = t.getStr())))
-
-  timeline.marks = timeline.marks.sorted(
-    proc(a, b: Mark): int = cmp(a.time, b.time))
-
-  return timeline
-
-proc saveTimeline(timeline: Timeline, location: string): void =
-  ## Write the timeline to disk at the file location given.
-
-  var timelineFile: File
-  try:
-    timelineFile = open(location, fmWrite)
-    timelineFile.writeLine(pretty(%timeline))
-  except: raise newException(IOError, "unable to save changes to " & location)
-  finally: close(timelineFile)
-
-proc flexFormat(i: TimeInterval): string =
   ## Pretty-format a time interval.
 
   let fmt =
-    if i > 1.days: "d'd' H'h' m'm'"
+    if i > initDuration(days = 1): "d'd' H'h' m'm'"
-    elif i >= 1.hours: "H'h' m'm'"
+    elif i >= initDuration(hours = 1): "H'h' m'm'"
-    elif i >= 1.minutes: "m'm' s's'"
+    elif i >= initDuration(minutes = 1): "m'm' s's'"
     else: "s's'"
 
   return i.format(fmt)
 
-type WriteData = tuple[idx: int, mark: Mark, prefixLen: int, interval: TimeInterval]
+type WriteData = tuple[idx: int, mark: Mark, prefixLen: int, interval: Duration]
 
 proc writeMarks(timeline: Timeline, indices: seq[int], includeNotes = false): void =
   ## Write a nicely-formatted list of Marks to stdout.
@@ -132,9 +48,9 @@ proc writeMarks(timeline: Timeline, indices: seq[int], includeNotes = false): vo
 
   let largestInterval = now - marks[idxs.first].time
   let timeFormat =
-    if largestInterval > 1.years: "yyyy-MM-dd HH:mm"
+    if largestInterval > initDuration(days = 365): "yyyy-MM-dd HH:mm"
-    elif largestInterval > 7.days: "MMM dd HH:mm"
+    elif largestInterval > initDuration(days = 7): "MMM dd HH:mm"
-    elif largestInterval > 1.days: "ddd HH:mm"
+    elif largestInterval > initDuration(days = 1): "ddd HH:mm"
     else: "HH:mm"
 
   var toWrite: seq[WriteData] = @[]
@@ -143,7 +59,7 @@ proc writeMarks(timeline: Timeline, indices: seq[int], includeNotes = false): vo
 
   for i in idxs:
     let
-      interval: TimeInterval =
+      interval: Duration =
         if (i == marks.len - 1): now - marks[i].time
         else: marks[i + 1].time - marks[i].time
       prefix =
@@ -188,23 +104,6 @@ proc writeMarks(timeline: Timeline, indices: seq[int], includeNotes = false): vo
         writeLine(stdout, spaces(notesPrefixLen) & line)
       writeLine(stdout, "")
 
-proc findById(marks: seq[Mark], id: string): int =
-  var idx = 0
-  for mark in marks:
-    if startsWith($mark.id, id): return idx
-    inc(idx)
-
-  return -1
-
-proc getLastIndex(marks: seq[Mark]): int =
-  ## Find and return the index of the last Mark that was not a STOP mark.
-  ## Returns -1 if there is no such last mark.
-
-  var idx = marks.len - 1
-  while idx >= 0 and marks[idx].summary == STOP_MSG: idx -= 1
-  if idx < 0: result = -1
-  else: result = idx
-
 proc doInit(timelineLocation: string): void =
   ## Interactively initialize a new timeline at the given file path.
 
@@ -224,10 +123,12 @@ proc doInit(timelineLocation: string): void =
 
 type ExpectedMarkPart = enum Time, Summary, Tags, Notes
 
-proc edit(mark: var Mark): void =
+proc edit(mark: Mark): Mark =
   ## Interactively edit a mark using the editor named in the environment
   ## variable "EDITOR"
 
+  result = mark
+
   var
     tempFile: File
     tempFileName: string
@@ -243,8 +144,10 @@ proc edit(mark: var Mark): void =
     tempFile.writeLine(
       """# Everything from the line below to the end of the file will be considered
 # notes for this timeline mark.""")
+    tempFile.write(mark.notes)
 
     close(tempFile)
+    tempFile = nil
 
     discard os.execShellCmd "$EDITOR " & tempFileName & " </dev/tty >/dev/tty"
 
@@ -252,12 +155,13 @@ proc edit(mark: var Mark): void =
 
     for line in lines tempFileName:
       if strip(line)[0] == '#': continue
-      elif markPart == Time: mark.time = parseTime(line); markPart = Summary
+      elif markPart == Time: result.time = parseTime(line); markPart = Summary
-      elif markPart == Summary: mark.summary = line; markPart = Tags
+      elif markPart == Summary: result.summary = line; markPart = Tags
       elif markPart == Tags:
-        mark.tags = line.split({',', ';'});
+        result.tags = line.split({',', ';'});
+        result.notes = ""
         markPart = Notes
-      else: mark.notes &= line & "\x0D\x0A"
+      else: result.notes &= line & "\x0D\x0A"
 
   finally: close(tempFile)
 
@@ -359,6 +263,7 @@ Usage:
   ptk current
   ptk sum-time --ids <ids>...
   ptk sum-time [options] [<firstId>] [<lastId>]
+  ptk serve-api <svcCfg> [--port <port>]
   ptk (-V | --version)
   ptk (-h | --help)
 
@@ -391,7 +296,7 @@ Options:
   let now = getTime().local
 
   # Parse arguments
-  let args = docopt(doc, version = "ptk 0.12.4")
+  let args = docopt(doc, version = PTK_VERSION)
 
   if args["--echo-args"]: echo $args
 
@@ -481,7 +386,7 @@ Options:
         summary: STOP_MSG,
         notes: args["--notes"] ?: "",
         tags: (args["--tags"] ?: "").split({',', ';'}).filterIt(not it.isNilOrWhitespace))
-        
+
       timeline.marks.add(newMark)
 
       timeline.writeMarks(
@@ -524,7 +429,7 @@ Options:
         notes: args["--notes"] ?: "",
         tags: (args["--tags"] ?: "").split({',', ';'}).filterIt(not it.isNilOrWhitespace))
 
-      if args["--edit"]: edit(newMark)
+      if args["--edit"]: newMark = edit(newMark)
 
       let prevLastIdx = timeline.marks.getLastIndex()
       timeline.marks.add(newMark)
@@ -546,7 +451,7 @@ Options:
         markToResumeIdx = timeline.marks.getLastIndex()
         if markToResumeIdx < 0: exitErr "No mark to resume."
       var markToResume = timeline.marks[markToResumeIdx]
-      
+
       var newMark: Mark = (
         id: genUUID(),
         time: if args["--time"]: parseTime($args["--time"]) else: now,
@@ -554,13 +459,13 @@ Options:
         notes: markToResume.notes,
         tags: markToResume.tags)
 
-      if args["--edit"]: edit(newMark)
+      if args["--edit"]: newMark = edit(newMark)
 
       timeline.marks.add(newMark)
       timeline.writeMarks(
         indices = sequtils.toSeq(markToResumeIdx..<timeline.marks.len),
         includeNotes = args["--verbose"])
-        
+
       saveTimeline(timeline, timelineLocation)
 
     if args["amend"]:
@@ -576,7 +481,7 @@ Options:
         if markIdx < 0: exitErr "No mark to amend."
 
       var mark = timeline.marks[markIdx]
-      
+
       if args["<summary>"]: mark.summary = $args["<summary>"]
       if args["--notes"]: mark.notes = $args["<notes>"]
       if args["--tags"]:
@@ -591,7 +496,7 @@ Options:
         except: raise newException(ValueError,
           "invalid value for --time: " & getCurrentExceptionMsg())
 
-      if args["--edit"]: edit(mark)
+      if args["--edit"]: mark = edit(mark)
 
       timeline.marks.delete(markIdx)
       timeline.marks.insert(mark, markIdx)
@@ -634,8 +539,8 @@ Options:
           includeNotes = true)
 
     if args["sum-time"]:
-    
+
-      var intervals: seq[TimeInterval] = @[]
+      var intervals: seq[Duration] = @[]
 
       if args["--ids"]:
         for id in args["<ids>"]:
@@ -662,7 +567,17 @@ Options:
       else:
         let total = intervals.foldl(a + b)
         echo flexFormat(total)
- 
+
+    if args["serve-api"]:
+
+      if not fileExists($args["<svcCfg>"]):
+        exitErr "cannot find service config file: '" & $args["<svcCfg>"]
+
+      var apiCfg = loadApiConfig(parseFile($args["<svcCfg>"]))
+      if args["--port"]: apiCfg.port = parseInt($args["--port"])
+
+      start_api(apiCfg)
+
  except:
   fatal "ptk: " & getCurrentExceptionMsg()
   quit(QuitFailure)

ptk.nimble

@@ -1,6 +1,6 @@
 # Package
 
-version       = "0.12.4"
+version       = "1.0.4"
 author        = "Jonathan Bernard"
 description   = "Personal Time Keeper"
 license       = "MIT"
@@ -8,5 +8,19 @@ bin           = @["ptk"]
 
 # Dependencies
 
-requires @["nim >= 0.18.0", "docopt >= 0.6.4", "uuids", "langutils", "tempfile", "timeutils >= 0.2.2", "isaac >= 0.1.2"]
+requires @[
+  "nim >= 1.0.0",
+  "docopt >= 0.6.8",
+  "uuids",
+  "tempfile",
+  "isaac >= 0.1.3",
+  "bcrypt",
+  "jester 0.4.1",
+  "https://git.jdb-labs.com/jdb/nim-lang-utils.git",
+  "https://git.jdb-labs.com/jdb/nim-cli-utils.git",
+  "https://git.jdb-labs.com/jdb/nim-time-utils.git >= 0.5.2",
+  "https://git.jdb-labs.com/jdb/update-nim-package-version"
+]
 
+task updateVersion, "Update the version of this package.":
+  exec "update_nim_package_version ptk 'private/version.nim'"