include <./constants.scad>;

boardThickness = 6.4;
feltThickness = 2.4;
feltWidth = 12;
innerSide = kallaxSide - 2 * (feltThickness + boardThickness);

module feltStrip() {
  color("DimGray") cube([feltThickness, kallaxDepth, feltWidth]);
}

module sideBoard() {
  difference() {
    color ("BurlyWood") cube([boardThickness, kallaxDepth, kallaxSide - 2*feltThickness]);
    color("black") translate([0.2, 100, 30]) rotate([90, 0, -90]) linear_extrude(0.3)
      text(font="Iosevka", size=16, halign="center", valign="center", "side - plywood");
  }
}

module horizontalBoard() {
  difference() {
    color ("Wheat") cube([innerSide, kallaxDepth, boardThickness]);
    color("black") translate([110, 30, boardThickness - 0.2]) rotate([0, 0, 0]) linear_extrude(0.3)
      text(font="Iosevka", size=16, halign="center", valign="center", "top/bot - plywood");
  }
}

module outerBox() {
  translate([feltThickness, 0, feltThickness]) union() {
    // left and right side boards
    translate([0, 0, 0]) sideBoard();
    translate([innerSide + boardThickness , 0, 0]) sideBoard();

    // top and bottom horizontal boards
    translate([boardThickness, 0, 0]) horizontalBoard();
    translate([boardThickness, 0, innerSide + boardThickness]) horizontalBoard();

  }
}

module supportingFelt() {
  // felt strips for the left side
  translate([0, 0, feltThickness + 20]) feltStrip();
  translate([0, 0, (innerSide - feltThickness)/2]) feltStrip();
  translate([0, 0, feltThickness + innerSide - feltWidth - 20]) feltStrip();

  // felt strips for the right side
  translate([innerSide + feltThickness + 2*boardThickness, 0, feltThickness + 20]) feltStrip();
  translate([innerSide + feltThickness + 2*boardThickness, 0, (innerSide - feltThickness)/2]) feltStrip();
  translate([innerSide + feltThickness + 2*boardThickness, 0, feltThickness + innerSide - feltWidth - 20]) feltStrip();

  // felt strips for the top
  translate([feltWidth + boardThickness + 20, 0, 0]) rotate([0, -90, 0]) feltStrip();
  translate([(kallaxSide - feltWidth)/2, 0, 0]) rotate([0, -90, 0]) feltStrip();
  translate([kallaxSide - feltWidth - 20, 0, 0]) rotate([0, -90, 0]) feltStrip();

  // felt strips for the bottom
  translate([feltWidth + 20, 0,  kallaxSide - feltThickness]) rotate([0, -90, 0]) feltStrip();
  translate([(kallaxSide - feltWidth)/2, 0, kallaxSide - feltThickness]) rotate([0, -90, 0]) feltStrip();
  translate([kallaxSide - feltWidth - 20, 0, kallaxSide - feltThickness]) rotate([0, -90, 0]) feltStrip();
}